CompuLAB-Ansteuerung in VB





Das folgende VB-Programm zeigt alle Grundfunktionen und realisiert ein einfaches Programm für Zugriffe auf alle Ein- und Ausgänge. Die Eingangsspannungen an den analogen Eingängen werden digital und mit einer einfachen Balkenanzeige dargestellt. Alle digitalen Anschlüsse sind über Checkboxes zugänglich.



Private Sub Form_Load()
 i = OPENCOM("COM1:19200,N,8,2")
 If i = 0 Then
    i = OPENCOM("COM2:19200,N,8,2")
    Option1.Value = True
 End If
 If i = 0 Then MsgBox ("COM Error")
 Timer1.Interval = 100
End Sub

Private Sub Form_Unload(Cancel As Integer)
  CLOSECOM
End Sub

Private Sub Option1_Click()
 CLOSECOM
 i = OPENCOM("COM1:19200,N,8,2")
 If i = 0 Then MsgBox ("COM1 Error")
End Sub

Private Sub Option2_Click()
 CLOSECOM
 i = OPENCOM("COM2:19200,N,8,2")
 If i = 0 Then MsgBox ("COM2 Error")
End Sub
Private Sub Dout(Data)
  SENDBYTE 72
  SENDBYTE Data
End Sub

Private Function Din()
  SENDBYTE 64
  Din = READBYTE
End Function

Private Function AinA()
  SENDBYTE 60
  AinA = READBYTE
End Function

Private Function AinB()
  SENDBYTE 58
  AinB = READBYTE
End Function

Private Sub Timer1_Timer()
  Data = 0
  Data = Data + Check1.Value
  Data = Data + Check2.Value * 2
  Data = Data + Check3.Value * 4
  Data = Data + Check4.Value * 8
  Data = Data + Check5.Value * 16
  Data = Data + Check6.Value * 32
  Data = Data + Check7.Value * 64
  Data = Data + Check8.Value * 128
  Dout Data
  Ua = AinA
  Shape1.Width = 50 + Ua * 15
  Text1.Text = Str$(Ua * 0.02) + " V"
  Ub = AinB
  Shape2.Width = 50 + Ub * 15
  Text2.Text = Str$(Ub * 0.02) + " V"
  Data = Din
  Check9.Value = Data And 1
  Check10.Value = (Data And 2) \ 2
  Check11.Value = (Data And 4) \ 4
  Check12.Value = (Data And 8) \ 8
  Check13.Value = (Data And 16) \ 16
  Check14.Value = (Data And 32) \ 32
  Check15.Value = (Data And 64) \ 64
  Check16.Value = (Data And 128) \ 128
End Sub


Download VB-Programm mit Quelltext und Exe (Compulabvb.zip, 9 KB)
Zusätzlich erforderlich: Die RSCOM.DLL